// nullstatus.txt
// By Lazarus
// Creature radiates null field, all positive status effects (except Invulnerability and Divinely touched) are removed from 
// nearby characters.
// Another Change: SDF's in this script are now increased, instead of set. This is for the NPC exp system.
// If flag is set and creature is a golem, is killed.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - How much to increase flag by.
//   Cell 2 - If add half an exp, then set this to 5.
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
if(get_flag(10,9) > 1)
	if(get_species(ME) == 11)
		kill_char(ME,2,0);
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
if(char_ok(4) == 1)
{	if(get_memory_cell(2) == 5)
		inc_flag(250,5,(get_ran(1,get_memory_cell(1),get_memory_cell(1) + 1)));
	if(get_memory_cell(2) != 5)
		inc_flag(250,5,get_memory_cell(1));
}
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it

	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

i = 0;
while(i <= 4)
{ if(char_ok(i) == 1)
		if((dist_to_char(i)) <= 1) {
		if(get_char_status(i,1) > 0)
			set_char_status(i,1,(-1 * (get_char_status(i,1))),1,0);
		if(get_char_status(i,2) > 0)
			set_char_status(i,2,(-1 * (get_char_status(i,2))),1,0);
		if(get_char_status(i,3) > 0)
			set_char_status(i,3,(-1 * (get_char_status(i,3))),1,0);
		set_char_status(i,5,(-1 * (get_char_status(i,5))),1,0);
		set_char_status(i,14,(-1 * (get_char_status(i,14))),1,0);
		set_char_status(i,15,(-1 * (get_char_status(i,15))),1,0);
		set_char_status(i,17,(-1 * (get_char_status(i,17))),1,0);
		set_char_status(i,22,(-1 * (get_char_status(i,22))),1,0);
			if(get_flag(4,7) == 0)
			{	message_dialog("This golem radiates a strange magical field. As you draw closer to it, you feel all your positive status effects being drained from you. The result leaves you weak and dizzy. This could be a tough fight.","");
				set_flag(4,7,1); }
			print_named_str(i," is drained of status effects.");
}
		i = i + 1; }

	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;